Método de la Secante

Lenguaje

PSeInt (Pseudocódigo)
Descripción

Encuentra la solución de f(x) = f(x)=x³+2x²+10x-20 con el método de la secante

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

SubProceso funcion_ <- f(x)

    funcion_ <- x*x*x + 2.0*x*x + 10.0*x - 20;

FinSubProceso

Algoritmo ProcesoSecante

    ITERACIONES_MAXIMAS <- 100;

    TOLERANCIA <- 0;

    Escribir "Método de la Secante para el cálculo de la función: f(x)=x³+2x²+10x-20";

    Escribir "";

    Escribir Sin Saltar "Ingrese la aproximación inicial x0:";

    Leer x0;

    Escribir Sin Saltar "Ingrese la aproximación inicial x1:";

    Leer x1;

    Escribir "";

    Escribir "n                   Xn                  Error";

    Escribir "0                   ", x0;

    n <- 1;

    Repetir

        err <- abs(x0-x1);

        Escribir n, "                   ", x1, "   ", err;

        Si err<>0 Entonces

            temp <- x1;

            x1 <- x1 - (x1 - x0) * f(x1) / (f(x1) - f(x0));

            x0 <- temp;

        FinSi

        n <- n+1;

    Hasta Que err<=TOLERANCIA O n>ITERACIONES_MAXIMAS

    Escribir "";

    Si n<ITERACIONES_MAXIMAS Entonces

        Escribir "La solución es: ", x1;

    Sino

        Escribir "No se encontro la raíz: cambiar aproximaciones iniciales o aumentar ITERACIONES_MAXIMAS";

    FinSi

FinAlgoritmo