Algoritmo ProcesoRomano
    Dimension romanos[4,9];
    romanos[1,1] <- "M";
    romanos[1,2] <- "MM";
    romanos[1,3] <- "MMM";
    romanos[2,1] <- "C";
    romanos[2,2] <- "CC";
    romanos[2,3] <- "CCC";
    romanos[2,4] <- "CD";
    romanos[2,5] <- "D";
    romanos[2,6] <- "DC";
    romanos[2,7] <- "DCC";
    romanos[2,8] <- "DCCC";
    romanos[2,9] <- "CM";
    romanos[3,1] <- "X";
    romanos[3,2] <- "XX";
    romanos[3,3] <- "XXX";
    romanos[3,4] <- "XL";
    romanos[3,5] <- "L";
    romanos[3,6] <- "LX";
    romanos[3,7] <- "LXX";
    romanos[3,8] <- "LXXX";
    romanos[3,9] <- "XC";
    romanos[4,1] <- "I";
    romanos[4,2] <- "II";
    romanos[4,3] <- "III";
    romanos[4,4] <- "IV";
    romanos[4,5] <- "V";
    romanos[4,6] <- "VI";
    romanos[4,7] <- "VII";
    romanos[4,8] <- "VIII";
    romanos[4,9] <- "IX";
    arabigo <- 0;
    multiplo <- 1000;
    Escribir "Ingrese un número romano: ";
    Leer original;
    original <- Mayusculas(original);
    romano <- original;
    Para i<-1 Hasta 4 Con Paso 1 Hacer
        Si i=1 Entonces
            j <- 3;
        Sino
            j <- 9;
        FinSi
        Mientras j>0 Hacer
            tamano <- Longitud(romanos[i,j]);
            Si romanos[i,j]=Subcadena(romano, 1, tamano) Entonces
                arabigo <- arabigo + j * multiplo;
                romano <- Subcadena(romano, tamano+1, Longitud(romano));
                j <- 0;
            FinSi
            j <- j-1;
        FinMientras
        multiplo <- multiplo / 10;
    FinPara
    Escribir "";
    Si Longitud(romano)=0 Entonces
        Escribir original, " = ", arabigo;
    Sino
        Escribir "El número romano ", original, " es incorrecto.";
    FinSi
FinAlgoritmo