Juego del Ahorcado

Lenguaje

PSeInt (Pseudocódigo)
Descripción

Juego del ahorcado para adivinar nombres de países.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92

Algoritmo ProcesoAhorcado

    PALABRAS_TAMANO <- 23;

    oportunidades <- 6;

    Dimension palabras[PALABRAS_TAMANO];

    palabras[1] <- "Argentina";

    palabras[2] <- "Belice";

    palabras[3] <- "Bolivia";

    palabras[4] <- "Brasil";

    palabras[5] <- "Canada";

    palabras[6] <- "Colombia";

    palabras[7] <- "Cuba";

    palabras[8] <- "Chile";

    palabras[9] <- "Ecuador";

    palabras[10] <- "El Salvador";

    palabras[11] <- "España";

    palabras[12] <- "Estados Unidos";

    palabras[13] <- "Guatemala";

    palabras[14] <- "Haiti";

    palabras[15] <- "Honduras";

    palabras[16] <- "Mexico";

    palabras[17] <- "Panama";

    palabras[18] <- "Paraguay";

    palabras[19] <- "Peru";

    palabras[20] <- "Puerto Rico";

    palabras[21] <- "Republica Dominicana";

    palabras[22] <- "Uruguay";

    palabras[23] <- "Venezuela";

    cabeza <- ' ';

    cuerpo <- ' ';

    mano_izquierda <- ' ';

    mano_derecha <- ' ';

    pie_izquierdo <- ' ';

    pie_derecho <- ' ';

    turnos <- 0;

    aciertos <- 0;

    palabra <- palabras[Azar(PALABRAS_TAMANO)+1];

    n <- Longitud(palabra);

    Dimension casillas(n);

    Para i<-1 Hasta n Con Paso 1 Hacer

        casillas[i] <- '_';

    FinPara

    Repetir

        Escribir "";

        Escribir "Oportunidades restantes: ", oportunidades-turnos;

        Para i<-1 Hasta n Con Paso 1 Hacer

            Escribir Sin Saltar " ", casillas[i];

        FinPara

        Escribir "";

        Escribir Sin Saltar "Escriba una letra: ";

        Leer letra;

        encontrado <- Falso;

        Para i<-1 Hasta n Con Paso 1 Hacer

            chr <- Subcadena(palabra, i, i);

            Si Mayusculas(letra)=Mayusculas(chr) Entonces

                encontrado <- Verdadero;

                Si casillas[i]='_' Entonces

                    casillas[i] <- chr;

                    aciertos <- aciertos+1;

                FinSi

            FinSi

        FinPara

        Si No encontrado Entonces

            turnos <- turnos+1;

            Escribir "Letra no encontrada.";

            Segun turnos Hacer

                1:

                    cabeza <- 'O';

                2:

                    cuerpo <- '+';

                3:

                    mano_derecha <- '/';

                4:

                    mano_izquierda <- '\';

                5:

                    pie_derecho <- '/';

                6:

                    pie_izquierdo <- '\';

            FinSegun

        FinSI

        Escribir "     ", cabeza," ";

        Escribir "    ", mano_derecha, cuerpo, mano_izquierda;

        Escribir "    ", pie_derecho," ", pie_izquierdo;

        Escribir "";

    Hasta Que turnos>=oportunidades O aciertos>=n;

    Si aciertos=n Entonces

        Escribir "Felicidades, has ganado.";

    Sino

        Escribir "Has perdido.";

    FinSi

    Escribir "La palabra secreta es: ", palabra;

FinAlgoritmo