Estadística de números positivos

Lenguaje

PSeInt (Pseudocódigo)
Descripción

Obtiene el menor, mayor, suma, promedio posición del menor, posición del mayor, cantidad de aprobados, porcentaje de aprobados, cantidad de reprobados y porcentaje de reprobados de una serie de números positivos.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

Algoritmo EstadisticaPositivos

    calificacion_aprobatoria <- 7;

    aprobados <- 0;

    maximo <- 0;

    minimo <- 0;

    n <- 1;

    porcentaje_aprobados <- 0;

    porcentaje_reprobados <- 0;

    posicion_mayor <- 0;

    posicion_menor <- 0;

    promedio <- 0;

    reprobados <- 0;

    suma <- 0;

    Repetir

        Escribir Sin Saltar "Ingrese el valor del elemento ", n, ":";

        Leer elemento;

        Si elemento>=0 Entonces

            Si n=1 O elemento<minimo Entonces

                minimo <- elemento;

                posicion_menor <- n;

            FinSi

            Si n=1 O elemento>maximo Entonces

                maximo <- elemento;

                posicion_mayor <- n;

            FinSi

            Si elemento < calificacion_aprobatoria Entonces

                reprobados <- reprobados + 1;

            Sino

                aprobados <- aprobados + 1;

            FinSi

            suma <- suma + elemento;

            n <- n + 1;

        FinSi

    Hasta Que elemento<0;

    n <- n - 1;

    Si n > 0 Entonces

        promedio <- suma / n;

        porcentaje_aprobados  <- 100.0 * aprobados  / n;

        porcentaje_reprobados <- 100.0 * reprobados / n;

    FinSi

    Escribir "";

    Escribir "Elementos         : ", n;

    Escribir "Menor             : ", minimo;

    Escribir "Posición del menor: ", posicion_menor;

    Escribir "Mayor             : ", maximo;

    Escribir "Posición del mayor: ", posicion_mayor;

    Escribir "Suma              : ", suma;

    Escribir "Promedio          : ", promedio;

    Escribir "Media aritmética  : ", promedio;

    Escribir "Aprobados         : ", aprobados;

    Escribir "Porcen. aprobados : ", porcentaje_aprobados , "%";

    Escribir "Reprobados        : ", reprobados;

    Escribir "Porcen. reprobados: ", porcentaje_reprobados, "%";

FinAlgoritmo