• Lenguaje

    PSeInt (Pseudocódigo)

  • Descripción

    En una asignatura hay estudiantes que están repitiendo por primera vez, repitiendo por segunda vez y tomando la asignatura por primera vez.
    El profesor ha decidido darles una AYUDA a los estudiantes así:
    - Los estudiantes que están tomando la asignatura por primera vez, tendrán un 10% adicional de la nota obtenida como definitiva.
    - Los estudiantes que están repitiendo, la materia por primera vez, obtendrán un 5% más de la nota obtenida como definitiva
    - Los estudiantes que están repitiendo la asignatura por segunda vez obtendrán un 2% más de la nota obtenida como definitiva.
    Determinar el valor a pagar por la matrícula teniendo en cuenta que:
    - Si repite por primera vez se le hace un descuento del 15%.
    - Si repite por segunda vez se le hace un 8% de descuento.
    - Si toma la asignatura por primera vez y es mujer se le hara un descuento del 20%.
    - Si toma la asignatura por primera vez y es hombre se le hara un 15% descuento.
    Además, para cada uno de los estudiantes del curso deberá indicar
    1) La nota obtenida como definitiva, calculada como el promedio de dos notas ingresadas por el usuario.
    2) La nota obtenida como definitiva luego de obtener la AYUDA del profesor.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
Proceso AyudaEnDefinitiva
    Escribir Sin Saltar "Ingresa el valor de matricula:";
    Leer matricula;
    Escribir Sin Saltar "Ingresa el valor de nota 1:";
    Leer nota_1;
    Escribir Sin Saltar "Ingresa el valor de nota 2:";
    Leer nota_2;
    Escribir "Selecciona el valor de condicion.";
    Escribir "    1.- Toma por primera vez";
    Escribir "    2.- Repitiendo por primera vez";
    Escribir "    3.- Repitiendo por segunda vez";
    Escribir Sin Saltar "    :";
    Repetir
        Leer condicion;
        Si condicion<1 O condicion>3 Entonces
            Escribir Sin Saltar "Valor incorrecto. Ingrésalo nuevamente.: ";
        FinSi
    Hasta Que condicion>=1 Y condicion<=3;
    Escribir "Selecciona el valor de genero.";
    Escribir "    1.- Hombre";
    Escribir "    2.- Mujer";
    Escribir Sin Saltar "    :";
    Repetir
        Leer genero;
        Si genero<1 O genero>2 Entonces
            Escribir Sin Saltar "Valor incorrecto. Ingrésalo nuevamente.: ";
        FinSi
    Hasta Que genero>=1 Y genero<=2;
    definitiva <- (nota_1+nota_2)/2;
    ayuda <- 0;
    descuento <- 0;
    Si condicion = 1 Entonces
        ayuda <- definitiva*0.10;
    FinSi
    Si condicion = 2 Entonces
        ayuda <- definitiva*0.05;
    FinSi
    Si condicion = 3 Entonces
        ayuda <- definitiva*0.02;
    FinSi
    definitiva_con_ayuda <- definitiva+ayuda;
    Si (condicion = 1 Y genero = 1) O condicion = 2 Entonces
        descuento <- matricula*0.15;
    FinSi
    Si condicion = 1 Y genero = 2 Entonces
        descuento <- matricula*0.2;
    FinSi
    Si condicion = 3 Entonces
        descuento <- matricula*0.08;
    FinSi
    matricula_con_descuento <- matricula-descuento;
    Escribir "Valor de ayuda: ", ayuda;
    Escribir "Valor de definitiva: ", definitiva;
    Escribir "Valor de definitiva con ayuda: ", definitiva_con_ayuda;
    Escribir "Valor de descuento: ", descuento;
    Escribir "Valor de matricula con descuento: ", matricula_con_descuento;
FinProceso