• Lenguaje

    PSeInt (Pseudocódigo)

  • Descripción

    Una cooperativa de ahorro y crédito establece las siguientes condiciones para determinar el valor máximo a prestar por cada línea de crédito.
    - Para líneas de crédito de Educación, viajes de vacaciones y calamidad doméstica se presta un máximo de tres veces al valor del ahorro del socio.
    - Para la línea de vehículo se presta un máximo de cinco veces el valor del ahorro del socio.
    - Para la línea de vivienda se presta un máximo de diez veces el valor del ahorro del socio.
    Se requiere calcular el valor máximo a prestarle a un socio de acuerdo a la línea de crédito solicitada y al valor del ahorro del socio. Las líneas de crédito se codifican como
    1= Educación, 2 = Vacaciones, 3=Vehículo, 4=Vivienda, 5=Calamidad.
    ‌Mostrar un mensaje en el caso de que no se registre uno de los códigos anteriores. Desarrollar el ejercicio de forma que se puede realizar el proceso tantas veces como se desee o se decida salir del mismo. Para todas las líneas de crédito se exige que el cliente tenga como mínimo $100,000 en ahorro para poder prestarle.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Proceso CooperativaDeAhorroYCredito
    Repetir
        Escribir Sin Saltar "Ingresa el valor de ahorro del socio:";
        Leer ahorro_del_socio;
        maximo <- 0;
        Escribir "Selecciona el valor de linea de credito.";
        Escribir "    1.- Educación";
        Escribir "    2.- Vacaciones";
        Escribir "    3.- Vehículo";
        Escribir "    4.- Vivienda";
        Escribir "    5.- Calamidad";
        Escribir Sin Saltar "    :";
        Repetir
            Leer linea_de_credito;
            Si linea_de_credito<1 O linea_de_credito>5 Entonces
                Escribir Sin Saltar "Valor incorrecto. Ingrésalo nuevamente.: ";
            FinSi
        Hasta Que linea_de_credito>=1 Y linea_de_credito<=5;
        Si linea_de_credito = 1 O linea_de_credito = 2 O linea_de_credito = 5 Entonces
            maximo <- ahorro_del_socio*3;
        FinSi
        Si linea_de_credito = 3 Entonces
            maximo <- ahorro_del_socio*5;
        FinSi
        Si linea_de_credito = 4 Entonces
            maximo <- ahorro_del_socio*10;
        FinSi
        Si ahorro_del_socio<100000 Entonces
            maximo <- 0;
            Escribir "No se puede prestar";
        FinSi
        Escribir "Valor de maximo: ", maximo;
        Escribir "";
        Repetir
            Escribir Sin Saltar "¿Deseas repetir el proceso? (S/N):";
            Leer tecla_repetir;
        Hasta Que tecla_repetir='s' O tecla_repetir='n' O tecla_repetir='S' O tecla_repetir='N'
    Hasta Que tecla_repetir='n' O tecla_repetir='N'
FinProceso