• Lenguaje

    PSeInt (Pseudocódigo)

  • Descripción

    Un tecnológico, ofrece un curso “x” y desea realizar un algoritmo que permita determinar y dar como salida la cantidad de dinero recaudado por concepto del curso; teniendo en cuenta que se tiene por cada participante la siguiente información:
    - Cédula de identidad
    - Nombre del participante
    - Procedencia (At = Alumno del Tecnológico, Dt = Docente del Tecnológico, Pg = Publico en General).
    Tomando en cuenta que la procedencia se cobra de la siguiente tarifa:
    - At = $10,000
    - Dt = $20,000
    - Pg = $35,000
    Nota: El cupo para el curso no es limitado.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Proceso CursoEnUnTecnologico2
    dinero_recaudado <- 0;
    Repetir
        Escribir Sin Saltar "Ingresa el cedula de identidad:";
        Leer cedula_de_identidad;
        Escribir Sin Saltar "Ingresa el nombre del participante:";
        Leer nombre_del_participante;
        tarifa <- 0;
        Escribir "Selecciona el valor de procedencia.";
        Escribir "    1.- At = Alumno del tecnológico";
        Escribir "    2.- Dt = Docente del tecnológico";
        Escribir "    3.- Pg = Público en general";
        Escribir Sin Saltar "    :";
        Repetir
            Leer procedencia;
            Si procedencia<1 O procedencia>3 Entonces
                Escribir Sin Saltar "Valor incorrecto. Ingrésalo nuevamente.: ";
            FinSi
        Hasta Que procedencia>=1 Y procedencia<=3;
        Si procedencia = 1 Entonces
            tarifa <- 10000;
        FinSi
        Si procedencia = 2 Entonces
            tarifa <- 20000;
        FinSi
        Si procedencia = 3 Entonces
            tarifa <- 35000;
        FinSi
        dinero_recaudado <- dinero_recaudado+tarifa;
        Escribir "Cedula de identidad: ", cedula_de_identidad;
        Escribir "Nombre del participante: ", nombre_del_participante;
        Escribir "Valor de tarifa: ", tarifa;
        Escribir "";
        Repetir
            Escribir Sin Saltar "¿Deseas repetir el proceso? (S/N):";
            Leer tecla_repetir;
        Hasta Que tecla_repetir='s' O tecla_repetir='n' O tecla_repetir='S' O tecla_repetir='N'
    Hasta Que tecla_repetir='n' O tecla_repetir='N'
    Escribir "Valor de dinero recaudado: ", dinero_recaudado;
FinProceso