Descuento para N clientes en lenguaje PSeInt (Pseudocódigo)

Lenguaje

PSeInt (Pseudocódigo)
Descripción

Un Supermercado necesita determinar el descuento para N clientes. Si el monto de la compra del cliente es mayor de S/. 5000 se le hará un descuento del 30%, si es menor o igual a S/. 5000 pero mayor que S/. 3000 será del 20%, si no rebasa los S/. 3000 pero si los S/. 1000 la rebaja efectiva es del 10% y en caso de que no rebase los S/. 1000 no tendrá beneficio.
Se pide:
a) Número de clientes que no obtuvieron descuento.
b) La mayor y menor compra.
c) El promedio de compra de los N clientes.
d) El total de descuentos otorgado.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

Proceso DescuentoParaNClientes

    clientes_sin_descuento <- 0;

    mayor_compra <- 0;

    menor_compra <- 0;

    promedio_de_compra <- 0;

    total_de_descuentos <- 0;

    Escribir Sin Saltar "Ingresa el valor de n:";

    Leer n;

    Para i<-1 Hasta n Con Paso 1 Hacer

        Escribir "PROCESO ", i;

        Escribir Sin Saltar "Ingresa el valor de monto de la compra:";

        Leer monto_de_la_compra;

        descuento <- 0;

        Si monto_de_la_compra>5000 Entonces

            descuento <- monto_de_la_compra*0.3;

        FinSi

        Si monto_de_la_compra>3000 Y monto_de_la_compra<=5000 Entonces

            descuento <- monto_de_la_compra*0.2;

        FinSi

        Si monto_de_la_compra>1000 Y monto_de_la_compra<=3000 Entonces

            descuento <- monto_de_la_compra*0.1;

        FinSi

        Si monto_de_la_compra<=1000 Entonces

            clientes_sin_descuento <- clientes_sin_descuento+1;

        FinSi

        total <- monto_de_la_compra-descuento;

        Si i = 1 O mayor_compra<monto_de_la_compra Entonces

            mayor_compra <- monto_de_la_compra;

        FinSi

        Si i = 1 O menor_compra>monto_de_la_compra Entonces

            menor_compra <- monto_de_la_compra;

        FinSi

        promedio_de_compra <- promedio_de_compra+monto_de_la_compra;

        total_de_descuentos <- total_de_descuentos+descuento;

        Escribir "Valor de descuento: ", descuento;

        Escribir "Valor de total: ", total;

        Escribir "";

    FinPara

    Si n = 0 Entonces

        promedio_de_compra <- 0;

    SiNo

        promedio_de_compra <- promedio_de_compra/n;

    FinSi

    Escribir "Valor de clientes sin descuento: ", clientes_sin_descuento;

    Escribir "Valor de mayor compra: ", mayor_compra;

    Escribir "Valor de menor compra: ", menor_compra;

    Escribir "Valor de promedio de compra: ", promedio_de_compra;

    Escribir "Valor de total de descuentos: ", total_de_descuentos;

FinProceso