Encuesta de número de hijos en lenguaje PSeInt (Pseudocódigo)

Lenguaje

PSeInt (Pseudocódigo)
Descripción

Se hizo una encuesta y se obtuvo los siguientes datos: cédula, estado civil, número de hijos; de (N) encuestas se desea sacar los siguientes datos:
a) Promedio de hijos de los casados.
b) El número de casados que no tienen hijos.
c) Promedio general de los hijos de los encuestados.
d) El número de solteros.
NOTA: Considere 1 si es soltero 2 si es casado.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

Proceso EncuestaDeNumeroDeHijos

    casados <- 0;

    casados_sin_hijos <- 0;

    solteros <- 0;

    promedio_hijos_de_casados <- 0;

    promedio_general <- 0;

    Escribir Sin Saltar "Ingresa el valor de n:";

    Leer n;

    Para i<-1 Hasta n Con Paso 1 Hacer

        Escribir "PROCESO ", i;

        Escribir Sin Saltar "Ingresa el cedula:";

        Leer cedula;

        Escribir Sin Saltar "Ingresa el valor de numero de hijos:";

        Leer numero_de_hijos;

        Escribir "Selecciona el valor de estado civil.";

        Escribir "    1.- soltero";

        Escribir "    2.- casado";

        Escribir Sin Saltar "    :";

        Repetir

            Leer estado_civil;

            Si estado_civil<1 O estado_civil>2 Entonces

                Escribir Sin Saltar "Valor incorrecto. Ingrésalo nuevamente.: ";

            FinSi

        Hasta Que estado_civil>=1 Y estado_civil<=2;

        Si estado_civil = 1 Entonces

            solteros <- solteros+1;

        SiNo

            casados <- casados+1;

            promedio_hijos_de_casados <- promedio_hijos_de_casados+numero_de_hijos;

        FinSi

        Si estado_civil = 2 Y numero_de_hijos = 0 Entonces

            casados_sin_hijos <- casados_sin_hijos+1;

        FinSi

        promedio_general <- promedio_general+numero_de_hijos;

        Escribir "Cedula: ", cedula;

        Escribir "";

    FinPara

    Si casados = 0 Entonces

        promedio_hijos_de_casados <- 0;

    SiNo

        promedio_hijos_de_casados <- promedio_hijos_de_casados/casados;

    FinSi

    Si n = 0 Entonces

        promedio_general <- 0;

    SiNo

        promedio_general <- promedio_general/n;

    FinSi

    Escribir "Valor de casados: ", casados;

    Escribir "Valor de casados sin hijos: ", casados_sin_hijos;

    Escribir "Valor de solteros: ", solteros;

    Escribir "Valor de promedio hijos de casados: ", promedio_hijos_de_casados;

    Escribir "Valor de promedio general: ", promedio_general;

FinProceso